init.sqs

Z Armed Assault nápověda

Popis

V tomto súbore si môžete ľahko a efektívne nakonfigurovať všetky potrebné nastavenia pre vašu misiu, ktoré sa majú vykonať ešte pred samotným spustením misie (nie Intra alebo Outra).

Tento súbor v podstate nahradzuje napríklad jednotlivé políčka v nastaveniach jednotiek - Inicializace:
Ak priamo v editore hry napíšete nejakej jednotke do tohto políčka napríklad:

[] exec "odpal.sqs"

... tak tento skript sa spustí zároveň so začiatkom misie.

Takýmto spôsobom môžete inicializovať veľa iných nastavení a skriptov, ale pri rozsiahlejších misiách tento spôsob rapídne stráca na prehľadnosti.
Preto je v tomto prípade vhodné použiť súbor s vyhradeným názvom init.sqs.

Štýl zápisu jednotlivých príkazov je rovnaký ako pri všetkých ostatných *.sqs súboroch pre ArmA. Môžete tu zadefinovať napríklad jednotlivé identity jednotiek, nastavenia výzbroje, nastaviť zobrazenie úloh v briefingu atď ... (viď. príklad kódu)

Pomocou tohto súboru môžete takisto efektne vytvoriť a samozrejme aj spustiť malý filmový úvod do misie priamo z briefingu. Teraz nieje myslené priamo Intro, ale krátka filmová ukážka po prečítaní briefingu hráčom. Štandardne totiž nasleduje začiatok misie z pohľadu hráčovej jednotky, ale vy si môžete na konci tohto súboru nadefinovať vlastné zábery a uviesť tak hráča do deja trocha iným spôsobom.

Znamená to teda, že všetky nastavenia na začiatku súboru sa vykonajú okamžite po spustení misie a následne na to sa pripravia kamerové zábery po prepnutí hráča z briefingu priamo do hry.

Viac vám určite napovie ukážka kódu takéhoto súboru ...

[editovat]

init.sqs - príklad kódu

;-- nastavenia identit hraca a jeho teamu
aP SetIdentity "tom"
w1 SetIdentity "w1"
w2 SetIdentity "w2"

;-- presun hraca a jeho teamu na palubu Blackhawka
aP MoveInCargo heli
w1 MoveInCargo heli
w2 MoveInCargo heli

;-- nastavenie vyzbroje hraca
aP AddWeapon "Binocular"
aP RemoveMagazine "PipeBomb"
aP AddMagazine "30Rnd_556x45_StanagSD"
aP AddMagazine "30Rnd_556x45_StanagSD"
aP AddMagazine "30Rnd_556x45_StanagSD"
aP AddMagazine "30Rnd_556x45_StanagSD"
aP AddMagazine "15Rnd_9x19_M9SD"
aP AddMagazine "15Rnd_9x19_M9SD"
aP AddMagazine "15Rnd_9x19_M9SD"
aP AddMagazine "15Rnd_9x19_M9SD"

;-- nastavenie zajatca
cap SetIdentity "greg"
cap SetCaptive TRUE

;-- nastavenie neviditelnosti zmeny uloh v briefingu
"5" ObjStatus "HIDDEN"
"6" ObjStatus "HIDDEN"
"7" ObjStatus "HIDDEN"

;-- nastavenie sniperov na posede na kraji lesa
sniper STOP true
sniper2 STOP true

;-- nastavenie zbrani a municie v nakladnom priestore vrtulnika
heli AddWeaponCargo ["MP5SD",4]
heli AddWeaponCargo ["M24",1]
heli AddMagazineCargo ["30Rnd_9x19_MP5SD",64]
heli AddMagazineCargo ["5Rnd_762x51_M24",32]
heli AddMagazineCargo ["30Rnd_556x45_StanagSD",32]
heli AddMagazineCargo ["SmokeShell",16]
heli AddMagazineCargo ["HandGrenadeTimed",32]
heli AddMagazineCargo ["HandGrenade",32]

;-- prieskumne a vysadkove HIP-y
eheli SetFuel 0
ee_heli SetFuel 0

;-- nastavenie zvukov na nulu
0 FadeSound 0

;-- uvodna skladba na zaciatku misie
PlayMusic "mission_in"

;-- UVODNE INTRO PRIAMO V MISII -----------------------------------------------------------

_camera = "camera" camcreate [5012.61,1893.39,30]
_camera cameraeffect ["internal","back"] 

_camera camPrepareTarget [-94354.87,-1966.77,10509.37]
_camera camPreparePos [5016.81,1893.42,1.99]
_camera camPrepareFOV 0.5
_camera camCommitPrepared 9
@camCommitted _camera

3 FadeMusic 0
3 FadeSound 0

CutText ["Rahmadi\n\n16:05","BLACK OUT"]
~4

_camera camPrepareFocus [-1,1]
_camera CameraEffect ["Terminate", "Back"]
CamDestroy _camera

exit

[editovat]